110 DIM A$[128]
120   CONTROL 10,5 ; 48
130 CONTROL 10,3 ; 15 ! 9600 BAUDS
200 IMAGE #,B
1000 CLEAR
1010 DISP "  ---------------------------"
1020 DISP "  | Receiver for TEXT files |"
1025 DISP "  ---------------------------"
1030 DISP @ DISP "  (c) 2011 guillaume.tello@orange.fr"
2000 DISP @ DISP "  Waiting for the file name..."
2010 ENTER 10 ; F$
2020 DISP "  Name is         : ";F$
2030 OUTPUT 10 USING 200 ; 86
2040 ENTER 10 ; A$
2050 T=VAL (A$)
2060 DISP "  # of blocks     : ";T
2070 CREATE F$,T
2080 ASSIGN# 1 TO  F$
2090 DISP "  File created"
2100 OUTPUT 10 USING 200 ; 86
2110 ENTER 10 ; A$
2120 L=VAL (A$)
2130 DISP "  # of lines      : ";L
2140 DISP @ DISP "  Receiving lines..."
2150 DISP
2160 OUTPUT 10 USING 200 ; 86
2170 FOR I=1 TO L
2180 ENTER 10 ; A$
2190 PRINT# 1 ; A$
2200 DISP A$
2210 OUTPUT 10 USING 200 ; 86
2220 NEXT I
2230 ASSIGN# 1 TO  *
2240 DISP
2250 DISP "  File received !"
2260 DISP
2270 DISP "  Now type this:"
2275 DISP "  --------------" @ DISP
2280 DISP "  SCRATCH (to clear memory)"
2285 DISP "  -> eventually ASSEMBLER if working with an ASM source"
2290 DISP "  GET ";CHR$ (34);F$;CHR$ (34);" (to load the program)"
2300 DISP "  STORE ";CHR$ (34);"filename";CHR$ (34);" (to save a BASIC PROG)"
2310 DISP "  -> or use ASTORE if it is an ASSEMBLY source"
2320 DISP "  PURGE ";CHR$ (34);F$;CHR$ (34);" (to remove text file)"
2330 DISP @ DISP "  Bye..."
2340 END